Qt 5.9 | Qt Bluetooth | Bluetooth Low Energy Heart Rate Game | App.qml Example File

Qt 5.9.9 Reference Documentation

# App.qml Example File

heartrate-game/qml/App.qml

      /***************************************************************************
      **
      ** Copyright (C) 2017 The Qt Company Ltd.
      ** Contact: https://www.qt.io/licensing/
      **
      ** This file is part of the examples of the QtBluetooth module of the Qt Toolkit.
      **
      ** $QT_BEGIN_LICENSE:BSD$
      ** Commercial License Usage
      ** Licensees holding valid commercial Qt licenses may use this file in
      ** accordance with the commercial license agreement provided with the
      ** Software or, alternatively, in accordance with the terms contained in
      ** a written agreement between you and The Qt Company. For licensing terms
      ** and conditions see https://www.qt.io/terms-conditions. For further
      ** information use the contact form at https://www.qt.io/contact-us.
      **
      ** BSD License Usage
      ** Alternatively, you may use this file under the terms of the BSD license
      ** as follows:
      **
      ** "Redistribution and use in source and binary forms, with or without
      ** modification, are permitted provided that the following conditions are
      ** met:
      **   * Redistributions of source code must retain the above copyright
      **     notice, this list of conditions and the following disclaimer.
      **   * Redistributions in binary form must reproduce the above copyright
      **     notice, this list of conditions and the following disclaimer in
      **     the documentation and/or other materials provided with the
      **     distribution.
      **   * Neither the name of The Qt Company Ltd nor the names of its
      **     contributors may be used to endorse or promote products derived
      **     from this software without specific prior written permission.
      **
      **
      ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
      ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
      ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
      ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
      ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
      ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
      ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
      ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
      ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
      ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
      ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
      **
      ** $QT_END_LICENSE$
      **
      ****************************************************************************/

      import QtQuick 2.5

      Item {
          id: app
          anchors.fill: parent
          opacity: 0.0

          Behavior on opacity { NumberAnimation { duration: 500 } }

          property var lastPages: []
          property int __currentIndex: 0

          function init()
          {
              opacity = 1.0
              showPage("Connect.qml")
          }

          function prevPage()
          {
              lastPages.pop()
              pageLoader.setSource(lastPages[lastPages.length-1])
              __currentIndex = lastPages.length-1;
          }

          function showPage(name)
          {
              lastPages.push(name)
              pageLoader.setSource(name)
              __currentIndex = lastPages.length-1;
          }

          TitleBar {
              id: titleBar
              currentIndex: __currentIndex

              onTitleClicked: {
                  if (index < __currentIndex)
                      pageLoader.item.close()
              }
          }

          Loader {
              id: pageLoader
              anchors.left: parent.left
              anchors.right: parent.right
              anchors.top: titleBar.bottom
              anchors.bottom: parent.bottom

              onStatusChanged: {
                  if (status === Loader.Ready)
                  {
                      pageLoader.item.init();
                      pageLoader.item.forceActiveFocus()
                  }
              }
          }

          Keys.onReleased: {
              switch (event.key) {
              case Qt.Key_Escape:
              case Qt.Key_Back: {
                  if (__currentIndex > 0) {
                      pageLoader.item.close()
                      event.accepted = true
                  } else {
                      Qt.quit()
                  }
                  break;
              }
              default: break;
              }
          }

          BluetoothAlarmDialog {
              id: btAlarmDialog
              anchors.fill: parent
              visible: !connectionHandler.alive
          }
      }