Qt 5.9 | Qt 3D | Qt 3D: Planets QML Example | planetDB.vert Example File

Qt 5.9.9 Reference Documentation

# planetDB.vert Example File

planets-qml/shaders/es2/planetDB.vert

      /****************************************************************************
      **
      ** Copyright (C) 2014 Klaralvdalens Datakonsult AB (KDAB).
      ** Copyright (C) 2017 The Qt Company Ltd.
      ** Contact: https://www.qt.io/licensing/
      **
      ** This file is part of the Qt3D module of the Qt Toolkit.
      **
      ** $QT_BEGIN_LICENSE:BSD$
      ** Commercial License Usage
      ** Licensees holding valid commercial Qt licenses may use this file in
      ** accordance with the commercial license agreement provided with the
      ** Software or, alternatively, in accordance with the terms contained in
      ** a written agreement between you and The Qt Company. For licensing terms
      ** and conditions see https://www.qt.io/terms-conditions. For further
      ** information use the contact form at https://www.qt.io/contact-us.
      **
      ** BSD License Usage
      ** Alternatively, you may use this file under the terms of the BSD license
      ** as follows:
      **
      ** "Redistribution and use in source and binary forms, with or without
      ** modification, are permitted provided that the following conditions are
      ** met:
      **   * Redistributions of source code must retain the above copyright
      **     notice, this list of conditions and the following disclaimer.
      **   * Redistributions in binary form must reproduce the above copyright
      **     notice, this list of conditions and the following disclaimer in
      **     the documentation and/or other materials provided with the
      **     distribution.
      **   * Neither the name of The Qt Company Ltd nor the names of its
      **     contributors may be used to endorse or promote products derived
      **     from this software without specific prior written permission.
      **
      **
      ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
      ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
      ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
      ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
      ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
      ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
      ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
      ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
      ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
      ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
      ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
      **
      ** $QT_END_LICENSE$
      **
      ****************************************************************************/

      attribute vec3 vertexPosition;
      attribute vec3 vertexNormal;
      attribute vec2 vertexTexCoord;
      attribute vec4 vertexTangent;

      varying vec4 positionInLightSpace;
      varying vec3 lightDir;
      varying vec3 viewDir;
      varying vec2 texCoord;

      uniform mat4 viewMatrix;
      uniform mat4 lightViewProjection;
      uniform mat4 modelMatrix;
      uniform mat4 modelView;
      uniform mat3 modelViewNormal;
      uniform mat4 mvp;

      uniform float texCoordScale;

      uniform vec3 lightPosition;

      void main()
      {
          const mat4 shadowMatrix = mat4(0.5, 0.0, 0.0, 0.0,
                                         0.0, 0.5, 0.0, 0.0,
                                         0.0, 0.0, 0.5, 0.0,
                                         0.5, 0.5, 0.5, 1.0);

          positionInLightSpace = shadowMatrix * lightViewProjection * modelMatrix * vec4(vertexPosition, 1.0);

          // Pass through texture coordinates
          texCoord = vertexTexCoord * texCoordScale;

          // Transform position, normal, and tangent to eye coords
          vec3 normal = normalize(modelViewNormal * vertexNormal);
          vec3 tangent = normalize(modelViewNormal * vertexTangent.xyz);
          vec3 position = vec3(modelView * vec4(vertexPosition, 1.0));

          // Calculate binormal vector
          vec3 binormal = normalize(cross(normal, tangent));

          // Construct matrix to transform from eye coords to tangent space
          mat3 tangentMatrix = mat3 (
              tangent.x, binormal.x, normal.x,
              tangent.y, binormal.y, normal.y,
              tangent.z, binormal.z, normal.z);

          // Transform light direction and view direction to tangent space
          vec3 s = lightPosition - position;
          lightDir = normalize(tangentMatrix * vec3(viewMatrix * vec4(s, 1.0)));

          vec3 v = -position;
          viewDir = normalize(tangentMatrix * v);

          // Calculate vertex position in clip coordinates
          gl_Position = mvp * vec4(vertexPosition, 1.0);
      }