Qt 1.6 | Enginio Manual | Enginio QML Examples - Users | Login.qml Example File

Qt 1.6.3 Reference Documentation

# Login.qml Example File

users/Login.qml

      /****************************************************************************
      **
      ** Copyright (C) 2015 The Qt Company Ltd.
      ** Contact: http://www.qt.io/licensing/
      **
      ** This file is part of the QtEnginio module of the Qt Toolkit.
      **
      ** $QT_BEGIN_LICENSE:BSD$
      ** You may use this file under the terms of the BSD license as follows:
      **
      ** "Redistribution and use in source and binary forms, with or without
      ** modification, are permitted provided that the following conditions are
      ** met:
      **   * Redistributions of source code must retain the above copyright
      **     notice, this list of conditions and the following disclaimer.
      **   * Redistributions in binary form must reproduce the above copyright
      **     notice, this list of conditions and the following disclaimer in
      **     the documentation and/or other materials provided with the
      **     distribution.
      **   * Neither the name of The Qt Company Ltd nor the names of its
      **     contributors may be used to endorse or promote products derived
      **     from this software without specific prior written permission.
      **
      **
      ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
      ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
      ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
      ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
      ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
      ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
      ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
      ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
      ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
      ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
      ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
      **
      ** $QT_END_LICENSE$
      **
      ****************************************************************************/

      import QtQuick 2.1
      import Enginio 1.0
      import QtQuick.Controls 1.0
      import QtQuick.Layouts 1.0

      ColumnLayout {
          EnginioOAuth2Authentication {
              id: identity
              user: login.text
              password: password.text
          }
          anchors.fill: parent
          anchors.margins: 3
          spacing: 3

          TextField {
              id: login
              Layout.fillWidth: true
              placeholderText: "Username"
              enabled: enginioClient.authenticationState == Enginio.NotAuthenticated
          }

          TextField {
              id: password
              Layout.fillWidth: true
              placeholderText: "Password"
              echoMode: TextInput.PasswordEchoOnEdit
              enabled: enginioClient.authenticationState == Enginio.NotAuthenticated
          }

          Button {
              id: proccessButton
              Layout.fillWidth: true
          }

          TextArea {
              id: data
              text: "Not logged in.\n\n"
              readOnly: true
              Layout.fillHeight: true
              Layout.fillWidth: true

              Connections {
                  target: enginioClient
                  onSessionAuthenticated: {
                      data.text = data.text + "User '"+ login.text +"' is logged in.\n\n" + JSON.stringify(reply.data, undefined, 2) + "\n\n"
                  }
                  onSessionAuthenticationError: {
                      data.text = data.text + "Authentication of user '"+ login.text +"' failed.\n\n" + JSON.stringify(reply.data, undefined, 2) + "\n\n"
                  }
                  onSessionTerminated: {
                      data.text = data.text + "Session closed.\n\n"
                  }
              }
          }

          states: [
              State {
                  name: "NotAuthenticated"
                  when: enginioClient.authenticationState == Enginio.NotAuthenticated
                  PropertyChanges {
                      target: proccessButton
                      text: "Login"
                      onClicked: {
                          enginioClient.identity = identity
                      }
                  }
              },
              State {
                  name: "Authenticating"
                  when: enginioClient.authenticationState == Enginio.Authenticating
                  PropertyChanges {
                      target: proccessButton
                      text: "Authenticating..."
                      enabled: false
                  }
              },
              State {
                  name: "AuthenticationFailure"
                  when: enginioClient.authenticationState == Enginio.AuthenticationFailure
                  PropertyChanges {
                      target: proccessButton
                      text: "Authentication failed, restart"
                      onClicked: {
                          enginioClient.identity = null
                      }
                  }
              },
              State {
                  name: "Authenticated"
                  when: enginioClient.authenticationState == Enginio.Authenticated
                  PropertyChanges {
                      target: proccessButton
                      text: "Logout"
                      onClicked: {
                          enginioClient.identity = null
                      }
                  }
              }
          ]
      }