- Qt 5.5
- Qt Bluetooth
- Bluetooth QML Chat Example
- InputBox.qml Example File
- Qt 5.5.1 Reference Documentation

# InputBox.qml Example File

chat/InputBox.qml

    /****************************************************************************
    **
    ** Copyright (C) 2015 The Qt Company Ltd.
    ** Contact: http://www.qt.io/licensing/
    **
    ** This file is part of the examples of the QtBluetooth module.
    **
    ** $QT_BEGIN_LICENSE:BSD$
    ** You may use this file under the terms of the BSD license as follows:
    **
    ** "Redistribution and use in source and binary forms, with or without
    ** modification, are permitted provided that the following conditions are
    ** met:
    **   * Redistributions of source code must retain the above copyright
    **     notice, this list of conditions and the following disclaimer.
    **   * Redistributions in binary form must reproduce the above copyright
    **     notice, this list of conditions and the following disclaimer in
    **     the documentation and/or other materials provided with the
    **     distribution.
    **   * Neither the name of The Qt Company Ltd nor the names of its
    **     contributors may be used to endorse or promote products derived
    **     from this software without specific prior written permission.
    **
    **
    ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
    ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
    ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
    ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
    ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
    ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
    ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
    ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
    ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
    ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
    ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
    **
    ** $QT_END_LICENSE$
    **
    ****************************************************************************/

    import QtQuick 2.2

    FocusScope {
        id: focusScope
        width: 250; height: 28

        property string text: textInput.text
        signal clear

        onClear: {
            textInput.text=""
        }

        BorderImage {
            source: "images/lineedit-bg.png"
            width: parent.width; height: parent.height
            border { left: 4; top: 4; right: 4; bottom: 4 }
        }

        Text {
            id: typeSomething
            anchors.fill: parent; anchors.leftMargin: 8
            verticalAlignment: Text.AlignVCenter
            text: "Type something..."
            color: "gray"
            font.italic: true
            font.pointSize: 14
        }

        MouseArea {
            anchors.fill: parent
            onClicked: { focusScope.focus = true; }
        }

        TextInput {
            id: textInput
            anchors { left: parent.left; leftMargin: 8; right: clear.left; rightMargin: 8; verticalCenter: parent.verticalCenter }
            focus: true
            selectByMouse: true
            font.pointSize: 14
        }

        Image {
            id: clear
            anchors { right: parent.right; rightMargin: 8; verticalCenter: parent.verticalCenter }
            source: "images/clear.png"
            opacity: 0

            MouseArea {
                // allow area to grow beyond image size
                // easier to hit the area on high DPI devices
                anchors.centerIn: parent
                height:focusScope.height
                width: focusScope.height
                onClicked: {
                    //toogle focus to be able to jump out of input method composer
                    focusScope.focus = false;
                    textInput.text = '';
                    focusScope.focus = true;
                }
            }
        }

        states: State {
            name: "hasText"; when: (textInput.text != '' || textInput.inputMethodComposing)
            PropertyChanges { target: typeSomething; opacity: 0 }
            PropertyChanges { target: clear; opacity: 1 }
        }

        transitions: [
            Transition {
                from: ""; to: "hasText"
                NumberAnimation { exclude: typeSomething; properties: "opacity" }
            },
            Transition {
                from: "hasText"; to: ""
                NumberAnimation { properties: "opacity" }
            }
        ]
    }