load("@fbcode//quic:defs.bzl", "mvfst_cpp_binary", "mvfst_cpp_library")
load("@fbcode_macros//build_defs:build_file_migration.bzl", "fbcode_target")
load("@fbsource//tools/build_defs:cell_defs.bzl", "get_fbsource_cell")

oncall("traffic_protocols")

mvfst_cpp_library(
    name = "tperf_client",
    srcs = [
        "TperfClient.cpp",
    ],
    headers = [
        "TperfClient.h",
    ],
    deps = [
        "fbsource//xplat/folly/io/async:async_udp_socket",
        "//fizz/crypto:utils",
        "//quic/common:mvfst_logging",
        "//quic/common/test:test_client_utils",
        "//quic/common/udpsocket:folly_async_udp_socket",
        "//quic/fizz/client/handshake:fizz_client_handshake",
    ],
    exported_deps = [
        "fbsource//xplat/folly/io/async:async_base",
        "fbsource//xplat/folly/stats:histogram",
        "//quic/client:client",
        "//quic/common/events:folly_eventbase",
    ],
)

mvfst_cpp_library(
    name = "tperf_server",
    srcs = [
        "TperfServer.cpp",
    ],
    headers = [
        "TperfServer.h",
    ],
    deps = [
        "fbsource//xplat/folly/io:iobuf",
        "fbsource//xplat/folly/stats:histogram",
        ":pacing_observer",
        "//fizz/crypto:utils",
        "//fizz/record:record",
        "//quic/common/test:test_utils",
        "//quic/common/udpsocket:folly_async_udp_socket",
        "//quic/congestion_control:static_cwnd_congestion_controller",
        "//quic/logging/oops_logger:glog_oops_logger",
    ],
    exported_deps = [
        "fbsource//xplat/folly/io/async:async_udp_socket",
        "//quic/api:quic_batch_writer",
        "//quic/common:mvfst_logging",
        "//quic/logging:file_qlogger",
        "//quic/observer:socket_observer_types",
        "//quic/server:accept_observer",
        "//quic/server:server",
    ],
)

mvfst_cpp_library(
    name = "tperf_tcp",
    srcs = [
        "TperfTcp.cpp",
    ],
    headers = [
        "TperfTcp.h",
    ],
    deps = [
        "fbsource//xplat/folly:network_address",
        "fbsource//xplat/folly/container:f14_hash",
        "fbsource//xplat/folly/io:iobuf",
        "fbsource//xplat/folly/io/async:async_base",
        "fbsource//xplat/folly/io/async:async_socket",
        "fbsource//xplat/folly/io/async:server_socket",
        "//fizz/client:async_fizz_client",
        "//fizz/client:fizz_client_context",
        "//fizz/crypto:utils",
        "//fizz/protocol:certificate_verifier",
        "//fizz/server:async_fizz_server",
        "//fizz/server:fizz_server_context",
        "//quic/common:mvfst_logging",
        "//quic/common/test:test_client_utils",
        "//quic/common/test:test_utils",
    ],
)

_TPERF_KNOBS_PATCHER_SRCS = (
    select({
        "DEFAULT": ["TperfKnobsPatcherXPlat.cpp"],
        "ovr_config//os/constraints:linux": ["TperfKnobsPatcherFbcode.cpp"],
    })
    if get_fbsource_cell() == "fbcode"
    else ["TperfKnobsPatcherXPlat.cpp"]
)

_TPERF_KNOBS_PATCHER_DEPS = (
    select({
        "DEFAULT": [],
        "ovr_config//os/constraints:linux": [
            "fbsource//xplat/folly:string",
            "//justknobs:justknobs_patches",
        ],
    })
    if get_fbsource_cell() == "fbcode"
    else []
)

mvfst_cpp_library(
    name = "tperf_knobs_patcher",
    srcs = _TPERF_KNOBS_PATCHER_SRCS,
    headers = ["TperfKnobsPatcher.h"],
    deps = ["//quic/common:mvfst_logging"] + _TPERF_KNOBS_PATCHER_DEPS,
)

_TPERF_DEPS = [
    ":tperf_client",
    ":tperf_knobs_patcher",
    ":tperf_server",
    ":tperf_tcp",
    "fbsource//xplat/folly/init:init",
    "fbsource//xplat/folly/portability:gflags",
    "fbsource//xplat/folly:string",
    "//quic/common:mvfst_logging",
] + select({
    "DEFAULT": ["fbsource//xplat/folly:memcpy-use"],
    "ovr_config//os:windows": [],
})

mvfst_cpp_binary(
    name = "tperf",
    srcs = [
        "tperf.cpp",
    ],
    deps = _TPERF_DEPS,
)

# Same tperf binary, built with the xsec_crypto AEAD backend instead of
# fizz/OpenSSL, matching prod revproxy (encrypt via xsec, decrypt via OpenSSL).
# The constraints are applied as cfg modifiers (like revproxy's proxygend) so
# they compose with the selected platform/build mode rather than pinning one.
# use_alt_crypto -> QUIC_DEFAULT_AEAD = XSecCryptoAead; force_alt_crypto -> the
# bridge always uses xsec (bypasses the JK). No flag; :tperf is the OpenSSL
# baseline. fbcode-cell only: the xsec sources live in fbcode/quic/facebook,
# whose xplat mirror is a header-less shadow stub.
fbcode_target(
    _kind = mvfst_cpp_binary,
    name = "tperf-xsec",
    srcs = [
        "tperf.cpp",
    ],
    modifiers = [
        "fbcode//quic:use_alt_crypto-enabled",
        "fbcode//quic:force_alt_crypto-enabled",
    ],
    deps = _TPERF_DEPS
    + [
        "//xsec_crypto/cpp20/haberdashery/aead/extensions:aes128gcm_zen4_extension",
    ],
)

fbcode_target(
    _kind = mvfst_cpp_binary,
    name = "tperf-xsec-zen4",
    srcs = [
        "tperf.cpp",
    ],
    modifiers = [
        "fbcode//quic:use_alt_crypto-enabled",
        "fbcode//quic:force_alt_crypto-enabled",
    ],
    deps = _TPERF_DEPS
    + [
        "//xsec_crypto/cpp20/haberdashery/aead/extensions:aes128gcm_zen4_benchmark_extension",
    ],
)

mvfst_cpp_library(
    name = "pacing_observer",
    headers = [
        "PacingObserver.h",
    ],
    exported_deps = [
        "//quic:constants",
        "//quic/api:transport",
        "//quic/common:mvfst_logging",
        "//quic/congestion_control:bandwidth",
        "//quic/state:quic_state_machine",
    ],
)
